Печать

Пожалуйста, войдите или зарегистрируйтесь.
1 час 1 день 1 неделя 1 месяц Навсегда

[prezervogaz]

Здравствуйте!
На днях начал разбираться с загрузчиком U-Boot и ОС Linux для платы Тион pro 2. Хотелось бы прояснить следующий момент.

На вашем сайте есть файл refl-linux примерно такого содержания:
setenv kern_file /tion_project/linux_kernel/uimage
setenv rd_file /tion_project/kfs/urootfs.arm.ext2
setenv kern_fladdr 60080000
setenv rd_fladdr   60300000
setenv rd_addr     800000
setenv fileaddr    0
setenv serverip 192.168.1.2
setenv ipaddr  192.168.1.100
setenv kern_flash 'tftpboot ${fileaddr} ${kern_file}; erase ${kern_fladdr} +${filesize}; cp.b ${fileaddr} ${kern_fladdr} ${filesize}'
setenv rd_flash 'tftpboot ${fileaddr} ${rd_file}; erase ${rd_fladdr} +${filesize}; cp.b ${fileaddr} ${rd_fladdr} ${filesize}; setenv rd_size ${filesize}'
setenv bootcmd 'echo Copy ramdisk to RAM...; cp.b ${rd_fladdr} ${rd_addr} ${rd_size}; bootm ${kern_fladdr} ${rd_addr}'
setenv reflash 'echo Re-flashing...; protect off all; run kern_flash; run rd_flash; imls; saveenv; echo Re-flash done'
setenv reload_script 'echo Reload script..; tftpboot 0x0 /tion_project/scripts/urefl-linux; autoscr 0x0; saveenv; echo Done'
setenv bootargs 'console=ttyAM0,57600n8 root=/dev/ram0'


У меня такой вопрос: откуда взялись цифры
setenv kern_fladdr 60080000
setenv rd_fladdr   60300000
setenv rd_addr     800000
setenv fileaddr    0
?

Как я понял, адресное пространство RAM и Flash объединено (так как команда cp используется для всех видов копирования). Если это так, то как узнать смещение (с которого начинается Flash-память) ? Привязаны ли эти цифры к mtdparts?

[asv]

> У меня такой вопрос: откуда взялись цифры
> setenv kern_fladdr 60080000
> setenv rd_fladdr   60300000
> setenv rd_addr     800000
> setenv fileaddr    0

http://zao-zeo.ru/dokuwiki/doku.php/tion-pro2#адреса_памяти

kern_fladdr, rd_fladdr -- расположены во Flash
rd_addr, fileaddr -- в RAM


> Если это так, то как узнать смещение (с которого начинается Flash-память) ?

flinfo в U-Boot

> Привязаны ли эти цифры к mtdparts?

Да

P.S. Если вам принципиально не нужен ramdisk использовать его смысла нет, можно использовать JFFS2 во Flash.

[prezervogaz]

Спасибо, разобрался